Database modèles Spice

[Christiancm]

Bonjour à tous,

Dans le tutorial "Tutorial LTspice, tracé de courbes de caractéristique etc .." (viewtopic.php?f=14&t=3402&p=71828#p71828, Bozole partage une librairie de modèles fiables.

Je propose dans ce topic, pour ceux qui le souhaitent, de regrouper les modèles Spice les plus fidèles afin que nous puissions partager et utiliser les mêmes ressources.

[Christiancm]

Je poursuis donc l'idée, voici l'ECL82:

.SUBCKT ECL82 A S G K
Eat at 0 VALUE={0.636*ATAN(V(A,K)/15)}
Egs gs 0 VALUE={LIMIT{V(S,K)/7+V(G,K)*1.3+V(A,K)/700,0,1E6}}
Egs2 gs2 0 VALUE={PWRS(V(gs),1.24)}
Ecath cc 0 VALUE={V(gs2)*V(at)}
Ga A K VALUE={3.45E-3*V(cc)}
Escrn sc 0 VALUE={V(gs2)*(1.1-V(at))}
Gs S K VALUE={3.7E-3*V(sc)*LIMIT{V(S,K),0,10}/10}
Gg G K VALUE={PWR(LIMIT{V(G,K)+1,0,1E6},1.5)*(1.25-V(at))*300E-6}
Cg1 G K 9.6p
Cak A K 9.3p
Cg1a G A 0.35p
.ENDS ECL82


(Va=200V Vg2=200V Ia=35mA Pamax=7W)

Ce modèle est très proche du datasheet de la Philips:
http://www.mif.pg.gda.pl/homepages/fran ... /ECL82.pdf

[bilbo_moria]

Bonne idée ! Je n'ai rien à apporter de complémentaire, pour le moment, mais je n'y manquerai pas si j'enrichis ma propre bibliothèque !

[roffli]

oui bonne idée. Ne faudrait-il pas partager un fichier .asc commun pour produire les courbes et ainsi vérifier la justesse du modèle ?
J'ai quelques modèles mais je n'ai jamais pris la peine de tracer leurs courbes...

EDIT: chuicon. c'est là:
http://vintageamps.free.fr/courbes.asc

[bilbo_moria]

Un modèle pour KT66, dérivé du site de Norman Koren. Le fichier de Norman Koren ne fonctionnait pas tel quel sous PSPICE, j'ai dû adapter un peu le format du modèle.

******************
.SUBCKT KT66 1 2 3 4 ; A G2 G1 C (Beam Tetrode)
* M-O Valve Co AKA Genalex
+ PARAMS: MU=11.68 EX=1.197 KG1=510.9 KG2=4500 KP=34 KVB=22.3
+ VCT=0.00 RGI=1000 CCG=16.0p CPG1=2.3p CCP=10.0p
RE1 7 0 1MEG ; DUMMY SO NODE 7 HAS 2 CONNECTIONS

E1 7 0 VALUE= ; E1 BREAKS UP LONG EQUATION FOR G1.
+{V(2,4)/KP*LOG(1+EXP((1/MU+V(3,4)/V(2,4))*KP))}

G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}

G2 2 4 VALUE={(EXP(EX*(LOG((V(2,4)/MU)+V(3,4)))))/KG2}

RCP 1 4 1G ; FOR CONVERGENCE A - C

C1 3 4 {CCG} ; CATHODE-GRID 1 C - G1

C2 1 3 {CPG1} ; GRID 1-PLATE G1 - A
C3 1 4 {CCP} ; CATHODE-PLATE A - C
R1 3 5 {RGI} ; FOR GRID CURRENT G1 - 5
D3 5 4 DX ; FOR GRID CURRENT 5 - C
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS KT66

Datasheet Marconi (Vg2 = 400V) :

(en plus grand : http://cdn.tonegeek.com/wp-content/uplo ... g2400V.png)

Simulation :

(en plus grand : http://cdn.tonegeek.com/wp-content/uplo ... PSPICE.png)

[Glomet]

Voici pour les fan des basses tensions : l'ECC86

Code : Tout sélectionner

.SUBCKT ECC86  1 2 3 ; P G C (Triode)
+ PARAMS: MU= 14  EX= 1.044  KG1= 374.5  KP= 79.85 KVB=   7.5  VCT=  0.10 RGI=4000
+ CCG=3P  CGP=1.3P CCP=1.8P  ; ADD .05PF TO ADJACENT PINS; .005 TO OTHERS.
E1 7 0 VALUE=
+{V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))}
RE1 7 0 1G
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1}
RCP 1 3 1G    ; TO AVOID FLOATING NODES IN MU-FOLLOWER
C1 2 3 {CCG}  ; CATHODE-GRID
C2 2 1 {CGP}  ; GRID=PLATE
C3 1 3 {CCP}  ; CATHODE-PLATE
D3 8 3 DX     ; FOR GRID CURRENT
R1 2 8 {RGI}  ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS
*$

[chanmix51]

Bonjour à tous,

Pour ceux que ça intéresse, voici mes fichiers de modélisation de tubes (essentiellement des russes).

russian_tubes.zip

(6.85 Kio) Téléchargé 801 fois

my_tubes.zip

(8.58 Kio) Téléchargé 677 fois

Amicalement,
Grégoire

[Christiancm]

Merci pour le partage Grégoire

[chanmix51]

Bonjour,

Actuellement à la recherche de DS de GU29 avec les courbes et animé du fol espoir de trouver un modèle LTSPice pour ce tube, j'ai trouvé ça cette semaine... J'ai pensé à vous.

tetrode.zip

(3.55 Kio) Téléchargé 612 fois

Amicalement,
Grégoire

[Lemontheo]

Salut,

je cherche un modèle de 12BH7 et d'ECC99.
Si quelqu'un a...

[McColson]

Je vais voir si je trouves ça qq part !

[Lemontheo]

Je te remercie. Je m'en suis sorti! J'ai compris comment créer un .lib et l'intégrer!

[bilbo_moria]

Tu as téléchargé le lib (le modèle) quelque part ou bien tu l'as créé toi-même ?

[Lemontheo]

J'ai récupéré le texte que j'ai collé dans bloc note que j'ai sauvegardé en .lib, que j'ai glissé dans le dossier adéquat

[bilbo_moria]

Ah, ok !